Hoe kan ik na een verse Windows-installatie - XP of 7 - Windows-updates “forceren”?
Ik wil niet na een week met “oude” Windows updates zitten, dus kan het in “één stap”? Zijn er “magische” commando’s die Windows dwingen te controleren op updates, en als die er zijn, ze te installeren?
Naast de gebruikelijke manier om Windows Update te gebruiken, kunt u een controle forceren vanaf een commandoregel.
Open een beheerdersopdrachtprompt en voer uit:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe is de AutoUpdate Client van Windows Update en wordt gebruikt om te controleren op beschikbare updates (voor de verschillende versies van het MS Windows platform) van Microsoft Update.
Dit zal geen installatie forceren.
U kunt met een script automatisch controleren op updates en deze installeren. Dit werkt zowel in XP als in Windows 7.
Er zijn een aantal scripts beschikbaar om te downloaden, hier is het mijne :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
Je voert dit vanaf de commandoregel als volgt uit:
cscript wsusupdate.vbs
Mijn script is slechts minimaal functioneel, maar kan toch nuttig zijn. Er zijn andere scripts beschikbaar met veel extra mogelijkheden, zoek maar eens op Google.
Een andere manier om een echte nieuwe scan voor updates te forceren is om de lei schoon te vegen, door alle updates te verwijderen die zijn opgeslagen in %windir%Windows\SoftwareDistributieDownload :
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
Ga dan naar Windows Update, en “Controleer op updates”. Het kan een uur duren, omdat elk updatebaar bestand op uw systeemvolume wordt gecontroleerd (volgende “Controles op updates” zullen snel zijn). Deze aanpak elimineert fouten en mislukte updates, en levert een schoon, up-to-date systeem op, althans voor zover MS dat ziet.
ik gebruik een tool van een tweede partij genaamd wuinstall voor het updaten van een verse windows installatie. daarmee kun je het hele updateproces automatiseren, inclusief automatische reboots. ik denk dat het een van de snelste manieren is om een verse windows up-to-date te krijgen zonder dat de gebruiker daarbij aanwezig is.
Ik heb gemerkt dat als je, als onderdeel van je nieuwe installatie op Windows 7, IE hebt geüpgraded of je hebt IE nog niet gestart en de inleidende vragen beantwoord, dat Windows Update je een fout geeft. Ik heb ook nog geen manier gevonden om Windows Update over te schakelen naar Microsoft Update zonder via de GUI te gaan, dus ik start IE manueel op, initialiseer het en stel dan Windows Update in via de GUI, zodat ik kan overschakelen naar Microsoft Update en de initiële fout vermijden. Uw ervaring kan variëren.